PROCX DUPLO - Procx com Duas Condições no Excel

Neste artigo veja como fazer PROCX duplo, PROCX com duas condições ou mais no Excel.

Download Planilha Procx Duplo Excel - Procx com Duas Condições

Clique no botão abaixo para realizar o  download do arquivo de exemplo:

Procx Excel

A função Procx é realizar uma consulta de dados conforme condições definidas e retornar um valor.

Ela é uma melhoria para as funções PROCV e PROCH no Excel, sendo mais prática de utilizar e tendo novos recursos.

A sintaxe da função PROCX é:

=PROCX(pesquisa_valor; pesquisa_matriz; matriz_retorno; [se_não_encontrado]; [modo_correspondência]; [modo_pesquisa])

1. pesquisa_valor: Obrigatório. O código da chave a ser pesquisada, por exemplo o código de um cliente.
2. pesquisa_matriz: Obrigatório. Local aonde será pesquisada a chave.
3. matriz_retorno: Obrigatório. A lista de dados aonde serão retornados os dados.
4. [se_não_encontrado]: Não obrigatório. Esta função substitui o uso da função SE_ERRO em conjunto com a PROCV, permitindo nesse caso colocar “NÃO LOCALIZADO” por exemplo ou então “” para ficar vazio a célula.
5. [modo_correspondência]: Não obrigatório.A forma como será realizada a pesquisa, sendo o padrão 0 pois é a correspondência exata utilizada para buscas de códigos por exemplo.
   0: Correspondência exata
   -1:Correspondência exata ou próximo item menor
   1:Correspondência exata ou próximo item maior
   2:Correspondência de caractere coringa
6. [modo_pesquisa]: Não obrigatório.Esta é mais uma melhoria em relação ao PROCX. É importante entender como utilizar para evitar erros. O 1 e -1 se referem a busca padrão, observando item a item, mudando apenas a ordem da busca, e a pesquisa binária exige que os dados estejam classificados para funcionar, senão ela poderá retornar dados incorretos, a diferença é que a pesquisa binária é muito mais rápida.
   1: Pesquisar do primeiro ao último
   -1:Pesquisar do último ao primeiro
   2 : Pesquisa binária (ordem de classificação crescente)
   -2: Pesquisa binária (ordem de classificação decrescente)

Procx Duplo com Duas Condições no Excel

Vejamos o seguinte exemplo.

Temos uma lista com os dados de notas fiscais e desejamos retornar a informação de alguma das colunas, sendo definida a coluna a partir de uma seleção.

Para a consulta queremos retornar quando for um determinado vendedor, cliente e data.

A função procx como padrão realiza a consulta apenas de uma condição, usando uma única chave.

Mas vejamos como fazer par retornar com mais de uma condição o PROCX.

Para isso usamos a fórmula abaixo:

=PROCX(1;(tVendas[Vendedor]=C4)*(tVendas[Cliente]=C5)*(tVendas[Data]=C6);              PROCX(E4;tVendas[#Cabeçalhos];tVendas);"NE")

Entenda a fórmula:

Como primeiro parâmetro passamos 1, o valor que desejamos consultar, a nossa chave.

E no segundo parâmetro, que é aonde queremos consultar, passamos a seguinte fórmula:

(tVendas[Vendedor]=C4)*(tVendas[Cliente]=C5)*(tVendas[Data]=C6)

Ou seja, quando vendedor = C4, Cliente = C5 e Data = C6.

A multiplicação faz com que os retornos que são VERDADEIRO ou FALSO, sejam multiplicados uns pelos outros.

Retornando então uma matriz com 1 e 0.

{FALSO;FALSO;FALSO;VERDADEIRO;FALSO;...}* {FALSO;FALSO;FALSO;VERDADEIRO;FALSO;...} * {FALSO;FALSO;FALSO;VERDADEIRO;FALSO;...}

E como resultado temos: {0;0;0;1;0;0;0;0;0;0;0;0;0;0;0;0;...}

E no terceiro parâmetro passamos a coluna que desejamos como retorno.

Para isso usamos a função PROCX novamente, para buscar a coluna que está selecionada na célula logo ao lado em E4.

PROCX(E4;tVendas[#Cabeçalhos];tVendas)

A consulta é feita no nome das colunas do relatório.

Como resultado temos a coluna selecionada, no caso abaixo o nome da empresa:

Download Planilha Procx Duplo Excel 2 Condições

Clique no botão abaixo para realizar o  download do arquivo de exemplo: