Procv Entre Planilhas Excel

Veja passo-a-passo como realizar PROCV entre planilhas no Excel.

O Procv é uma função de busca vertical do Excel. Com ela nós podemos retornar dados à partir de intervalos no Excel.

Mas como fazer a consulta entre planilhas no Excel, ou ainda mudando o nome da planilha dinamicamente?

Exemplo 1 Procv Entre Planilhas

Neste nosso primeiro exemplo iremos realizar o Procv no Excel nós temos a situação de consulta entre valores de orçamentos de departamentos, cada uma em uma planilha.

No nosso exemplo temos 3 planilhas com os departamentos:

Fiscal
Financeiro
Contábil

Todas as 3 planilhas contém dados de Mês, valor do orçamento e realizado e precisamos retornar os dados conforme o mês e o departamento.

Para retornar os dados de uma outra planilha através de PROCV nós usamos da seguinte forma:

=PROCV(B10;Fiscal!$B$8:$C$19;2;0)

No primeiro parâmetro passamos o que será consultado, no segundo temos o intervalo de onde será retornada a informação, no caso Fiscal que é a planilha daonde iremos retornar os dados.

Para isso, no segundo parâmetro basta selecionar o intervalo clicando em outra planilha.

Como o intervalo fica fixo e gostaríamos de retornar para outros departamentos, fizemos a seguinte fórmula:

=PROCV($B$8;INDIRETO($B10&"!$B$8:$D$19");2;0)

Veja que temos o uso do INDIRETO, unindo então o Fiscal e o intervalo de células: INDIRETO($B10&"!$B$8:$D$19") e em B8 temos o mês que está sendo pesquisado.

O mesmo foi aplicado também para a coluna realizado, mudando apenas a coluna que queremos retornar:

PROCV(valor_procurado;matriz_tabela;núm_índice_coluna;[procurar_intervalo])

valor_procurado: Valor que é pesquisado no intervalo. O valor pesquisado deve estar na primeira coluna da matriz_tabela.
matriz_tabela: Intervalo de busca.
núm_índice_coluna: Número da coluna que desejamos retornar.
[procurar_intervalo]: 0 para consulta exata e 1 para busca aproximada. Por padrão usamos 0 na maioria dos casos.

Exemplo 2 Procv Entre Planilhas com Índice Corresp

No segundo exemplo iremos retornar os dados usando Índice, Corresp e Indireto, montando assim uma fórmula mais dinâmica e que busca automaticamente a coluna.

No novo exemplo usamos também intervalos de tabelas.

O uso de tabelas é sempre recomendado nas bases de dados do Excel, pois assim o intervalo nas fórmulas será automaticamente ajustado e não é necessário selecionar as colunas inteiras ou um intervalo maior de dados.

Para isto selecione o intervalo e pressione ALT+T+A e converta.

Coloque um nome na tabela clicando em Design de Tabela.

Nela nós colocamos os mesmos nomes das planilhas para facilitar o entendimento do exemplo.

Para realizar um procv entre planilhas usando tabelas temos a seguinte fórmula:

=ÍNDICE(Fiscal;CORRESP($B$8;Fiscal[Mês];0);CORRESP(C$9;Fiscal[#Cabeçalhos];0))

Veja que nós temos acima o intervalo citado apenas o nome da tabela. Em vermelho nós temos o nome da tabela, veja que é citado em várias partes da fórmula, aonde temos a tabela como origem dos dados, coluna de consulta da linha e consulta da coluna de retorno.

Veja mais sobre as funções Índice e Corresp - Como Utilizar.

Abaixo temos a imagem de como fica a fórmula na planilha:

=ÍNDICE(INDIRETO($B10);CORRESP($B$8;INDIRETO($B10&"[Mês]");0);CORRESP(C$9;INDIRETO($B10&"[#Cabeçalhos]");0))

Nela usamos as funções Índice e Corresp, além de usar a Indireto para consultar a tabela conforme o nome na célula ao lado.

Exemplo 3 Procv Entre Várias Planilhas

Neste novo exemplo nós temos a situação de que todos os produtos estão em planilhas diferentes.

E gostaríamos de retornar conforme o produto selecionado na coluna de produto qual o estoque, preço e comissão da planilha.

As planilhas tem as iniciais dos produtos que as compõe:

As listas de dados tem a seguinte estrutura de dados:

Código
Loja
Produto
Estoque
Preço
Comissão

E como citado os produtos estão dispostos de forma que os produtos que começam com a letra A estão na planilha com esta letra e assim para todos os produtos.

Então usamos a seguinte fórmula, nela usamos o PROCV como no primeiro exemplo, e também usamos ESQUERDA para pegar a primeira letra à esquerda do nome do produto selecionado.

=PROCV(B9;INDIRETO(ESQUERDA($B9;1)&"!C:F");2;0)