Função DividirTexto Excel

Aprenda como usar a função DividirTexto no Excel passo-a-passo.

A função DividirTexto tem o objetivo de separar informações de um texto separando por um ou mais delimitadores determinados na função.

Como usar a Função DividirTexto Excel

Veja detalhes da função DividirTexto abaixo:

Nome: DIVIDIRTEXTO

Versão: Excel do Microsoft 365 Excel do Microsoft 365 para Mac Excel para a Web

Objetivo: A função DIVIDIRTEXTO funciona da mesma forma que o assistente de Texto para Colunas, mas na forma de fórmula. Ele permite dividir entre colunas ou para baixo por linhas. É o inverso da função UNIRTEXTO.

Sintaxe: =DIVIDIRTEXTO(text,col_delimiter,[row_delimiter],[ignore_empty], [match_mode], [pad_with])

Parâmetros:

• text: O texto que você deseja dividir. Obrigatório.
• col_delimiter: O texto que marca o ponto onde despejar o texto entre colunas.
• row_delimiter: O texto que marca o ponto em que o texto será despejado nas linhas. Opcional.
• ignore_empty: Especifique TRUE para ignorar delimitadores consecutivos. O padrão é FALSE, que cria uma célula vazia. Opcional.
• match_mode: Especifique 1 para executar uma correspondência sem maiúsculas de maiúsculas de minúsculas. O padrão é 0, o que faz uma correspondência sensível a casos. Opcional.
• pad_with: O valor com o qual preencher o resultado. O padrão é #N/A.

Dividir Texto em Colunas com a função DividirTexto Excel

No nosso exemplo temos os textos abaixo, separados por delimitadores ;.

O objetivo é separar estes dados usando uma função, no caso usaremos a DividirTexto do Excel.

Em uma coluna ao lado digitamos a seguinte função:

=DIVIDIRTEXTO(B6;";")

Com isso temos o texto dividido à partir do parâmetro ";" que passamos entre aspas duplas.

E arrastando para mais células temos:

Retornar Determinada Posição de Um Texto no Excel

No exemplo abaixo temos textos separados por |.

O objetivo é separar uma determinada informação de uma das colunas, sabendo que a sequência é a descrita abaixo em 1-Nota fiscal, 2-Data e assim por diante.

Para isso usamos a seguinte fórmula:

=ÍNDICE(DIVIDIRTEXTO(B6;"|");PROCX($D$5;$G$11:$G$17;$F$11:$F$17))

Nela usamos a função dividirtexto para separar os textos pelo delimitador | e usamos a função ÍNDICE para retornar determinada posição.

Poderíamos digitar um número ali e retornaria aquela coluna, ou também podemos usar o PROCX e retornar o número da coluna, como fizemos acima.

A aplicação da fórmula fica:

E aplicada temos o retorno apenas dos dados daquela coluna que desejamos extrair com o texto usando a função DividirTexto do Excel.

Juntar e Separar Textos no Excel

Temos uma lista de textos que desejamos juntar e em seguida separar em linhas.

Para isso usamos a fórmula:

=DIVIDIRTEXTO(UNIRTEXTO(";";;B7:B20);;";")

Nela unirmos os textos usando a função UNIRTEXTO e em seguida separarmos os textos usando a função DIVIDIRTEXTO.

No UnirTexto usamos também o ; como parâmetro da função UNIRTEXTO para concatenar os dados das linhas.

Veja a aplicação da fórmula:

Como resultado temos os textos todos unidos e separados abaixo um a um, linha a linha.

Separar Texto em Linhas e Colunas Com a Função DividirTexto Excel

Para separar os textos também podemos usar a função dividirtexto para quebrar linhas e colunas.

Veja que abaixo temos um texto em uma única célula.

Ela está separada por - para linhas e | para colunas.

Para isso usamos os dois parâmetros da função DIVIDIRTEXTO, col_delimiter e row_delimiter.

A função fica:

=DIVIDIRTEXTO(B6;"-";"|")

Como resultado temos:

Os dados ficam então separados por colunas e linhas à partir de uma única fórmula.

Extrair Texto de Células no Excel com a Função DividirTexto

No exemplo abaixo temos textos em células com texto e números.

O objetivo é extrair somente o texto destas células.

Para isso podemos também usar a função Dividirtexto do Excel.

A função que usamos foi:

=UNIRTEXTO(" ";;DIVIDIRTEXTO(B8;SEQUÊNCIA(10;;0;1)))

A fórmula acima usa SEQUÊNCIA para criar criar uma lista de separadores, estes separadores serão os números de 0 à 9. É passado no parâmetro col_delimiter da função DIVIDIRTEXTO.

Assim temos um texto separado em colunas usando os números como quebras, o que por si já extrai estes valores.

E usamos a função UNIRTEXTO para juntar os valores de cada uma das células separadas pela função DIVIDIRTEXTO.

Como resultado temos então os textos extraídos, eliminando todos os números:

Extrair Número de Células no Excel com a Função DividirTexto

Na situação abaixo veja como extrair somente números de células no Excel.

Para isso usamos o mesmo método que vimos para extrair os números, a diferença é que iremos criar quebrar usando uma lista de caracteres.

A fórmula para isto é:

=UNIRTEXTO(";";;DIVIDIRTEXTO(B8;EMPILHARV(CARACT(SEQUÊNCIA(47;;1;1));CARACT(SEQUÊNCIA(198;;58;1)))))

Veja que temos o uso da função CARACT.

A função caract no Excel converte um número em caractere alfabético.

Então usamos a função Sequência do Excel para gerar uma lista de números que representam as letras no alfabeto ASCII que vai de 0 à 255.

E unimos esta lista usando o EMPILHARV.

Estes dados são igualmente passados para a função DIVIDIRTEXTO para quebrar as colunas e com isso temos os dados quebrados e separados extraindo somente os números das células.

E por fim juntamos usando a função UNIRTEXTO e separando os números extraídos usando ; como delimitador.

O resultado que temos é o abaixo, extraindo inclusive mais do que um valor por célula no Excel:

Download Planilha DividirTexto Excel

Clique no botão abaixo para realizar o  download do arquivo de exemplo: