Como Converter Placas Mercosul Excel

Neste artigo você aprenderá como converter placas para o padrão Mercosul e vice-versa no Excel.

1. Modelo Mercosul vs Modelo anterior

O Modelo de placas do Mercosul apresenta em sua formação apenas a alteração de um caractere quando comparado ao modelo antigo. Em essência, os 4 primeiros caracteres da placa e os 2 últimos devem ser mantidos, com a alteração afetando apenas o 5º caractere.

A alteração é previsível e pode ser facilmente obtida no Excel usando fórmulas pela simples substituição de caracteres. A tabela a seguir mostra a correspondência (troca) que deve ser estabelecida com o 5º caractere das placas para termos a conversão.

Esta tabela é muito elucidativa: caso queiramos converter o modelo antigo para o padrão Mercosul, trocamos o 5º dígito da placa (que está em modelo antigo) pelo dígito correspondente na tabela acima, ou seja: localizamos este dígito na primeira coluna da tabela e inserimos em seu lugar o dígito equivalente da segunda coluna. Em resumo: trocaremos o número por uma letra. Caso desejemos converter o padrão Mercosul para o modelo antigo, trocamos o 5º dígito da placa (que está no padrão Mercosul) pelo dígito correspondente na tabela acima, ou seja: localizamos este dígito na segunda coluna da tabela e inserimos em seu lugar o dígito equivalente da primeira coluna. Em resumo: trocaremos a letra por um número.

Sendo assim, faremos o que chamamos de procedimento “de – para”. Ou seja: quando o 5º caractere da placa antiga for 6 deverá ser substituído pelo G, bem como se este 5º caractere for 0 deverá ser substituído por A para que se obtenha a placa no padrão Mercosul. E para o processo inverso: se quisermos obter a placa em modelo antigo que gerou o padrão Mercosul, quando o 5º caractere for a letra H devemos trocá-la pelo número 7 e quando este 5º caractere for a letra B deverá ser trocado por 1.

Neste sentido, este artigo objetiva expor soluções para estes casos com fórmulas no Excel.

2. Conversão das placas com fórmulas

2.1 - Do modelo anterior para o padrão Mercosul

Para as fórmulas propostas nesta conversão usaremos os seguintes dados:

a) Solução com a função MUDAR

Esta solução é cirúrgica e altera apenas o 5º caractere pelo seu equivalente. Com esta função indicamos o texto original (placa a ser convertida), a posição do caractere que desejamos trocar (5), o nº de caracteres que desejamos inserir em seu ligar (1) e o caractere novo, da substituição.

A imagem seguinte mostra uma fórmula proposta (=MUDAR(B3;5;1;PROCV(EXT.TEXTO(B3;5;1)+0;{0\"A";1\"B";2\"C";3\"D";4\"E";5\"F";6\"G";7\"H";8\"I";9\"J"};2;0))), que será explicada em seguida.

Nossa fórmula, que converte uma placa a partir de B3, é iniciada assim: =MUDAR(B3;5;1; . Nesta fórmula, B3 é o endereço da placa a converter, 5 é a posição do caractere que será trocado e 1 é a quantidade de caracteres que serão colocados em seu lugar, na substituição.

Nos resta entender agora a última parte da função MUDAR: seu quarto argumento (novo texto). Note na imagem que colocamos uma PROCV para informar o novo caractere que deverá ser inserido na substituição, através do trecho PROCV(EXT.TEXTO(B3;5;1)+0;{0\"A";1\"B";2\"C";3\"D";4\"E";5\"F";6\"G";7\"H";8\"I";9\"J"};2;0).

Essa PROCV pesquisa o 5º caractere para retornar seu equivalente. No entanto, precisamos da função EXT.TEXTO para obter este 5º caractere e por isso usamos o trecho EXT.TEXTO(B3;5;1). Com isso, temos o 5ª caractere e somamos 0 a este trecho para converter este caractere em número.

O segundo argumento, matriz de dados de PROCV, usou a matriz {0\"A";1\"B";2\"C";3\"D";4\"E";5\"F";6\"G";7\"H";8\"I";9\"J"} para localizar o 5º caractere já extraído e informado no primeiro argumento de PROCV e retornar seu equivalente. Esta matriz nada mais é do que os dados da tabela do tópico 1 deste artigo, encapsulada diretamente na fórmula. Com isso, não precisamos desta tabela em células, visto que usaríamos o seu intervalo na PROCV, como a imagem seguinte mostra (intervalo de H6 até I15):

Partindo da imagem anterior, podemos encapsular os dados de H6 a I15 na fórmula fazendo o seguinte: selecionamos o trecho H6:I15 na fórmula e pressionamos a tecla F9, que obteremos os dados diretamente na fórmula, ou seja: H6:I15 torna-se {0\"A";1\"B";2\"C";3\"D";4\"E";5\"F";6\"G";7\"H";8\"I";9\"J"} ao ser selecionado na fórmula, seguido do atalho F9.

b) Solução com concatenações e funções ESQUERDA e DIREITA

Esta solução une 3 partes que são concatenadas: a primeira parte - os 4 primeiros caracteres da placa, extraídos com a função ESQUERDA, a segunda parte - o 5º caractere extraído com a função EXT.TEXTO e trocado pelo equivalente usando PROCV e a terceira parte - os 2 últimos caracteres da placa, extraídos com a função DIREITA.

A imagem a seguir ilustra a fórmula aplicada, que foi =ESQUERDA(B3;4) & PROCV(EXT.TEXTO(B3;5;1)+0;{0\"A";1\"B";2\"C";3\"D";4\"E";5\"F";6\"G";7\"H";8\"I";9\"J"};2;0) & DIREITA(B3;2).

A segunda parte da concatenação é exatamente igual àquela usada no tópico a).

c) Soluções adicionais

A título de diversificação e exploração, as seguintes fórmulas também poderiam resultar na conversão desejada:

=MUDAR(B3;5;1;CONCAT(SE(EXT.TEXTO(B3;5;1)+0={0;1;2;3;4;5;6;7;8;9};{"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"};"")))

=MUDAR(B3;5;1;FILTRO({"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"};EXT.TEXTO(B3;5;1)+0={0;1;2;3;4;5;6;7;8;9}))

=ESQUERDA(B3;4)&CONCAT(SE(EXT.TEXTO(B3;5;1)+0={0;1;2;3;4;5;6;7;8;9};{"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"};"")) & DIREITA(B3;2)

=ESQUERDA(B3;4) & FILTRO({"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"};EXT.TEXTO(B3;5;1)+0={0;1;2;3;4;5;6;7;8;9}) & DIREITA(B3;2)

2.2 – Do padrão Placas Mercosul Excel para modelo anterior

Tomando como base as fórmulas apresentadas para a conversão a partir do padrão anterior para o padrão Mercosul, podemos obter o inverso com poucos ajustes.

Para as fórmulas propostas nesta conversão usaremos os seguintes dados:

a) Solução com a função MUDAR

Tomando como base a fórmula proposta em 2.1 a), precisaremos de fazer apenas 2 simples ajustes: não somar 0 ao resultado de EXT.TEXTO no primeiro argumento de PROCV (que resulta em uma letra) e inverter os vetores de busca no segundo argumento de PROCV.

A fórmula proposta então é: =MUDAR(B3;5;1;PROCV(EXT.TEXTO(B3;5;1);{"A"\0;"B"\1;"C"\2;"D"\3;"E"\4;"F"\5;"G"\6;"H"\7;"I"\8;"J"\9};2;0)). A imagem seguinte exibe os resultados obtidos.

b) Solução com concatenações e funções ESQUERDA e DIREITA

Tomando como base a fórmula proposta em 2.1 b), precisaremos de fazer apenas 2 simples ajustes: não somar 0 ao resultado de EXT.TEXTO no primeiro argumento de PROCV (que resulta em uma letra) e inverter os vetores de busca no segundo argumento de PROCV.

A fórmula proposta então é: =ESQUERDA(B3;4)& PROCV(EXT.TEXTO(B3;5;1);{"A"\0;"B"\1;"C"\2;"D"\3;"E"\4;"F"\5;"G"\6;"H"\7;"I"\8;"J"\9};2;0)&DIREITA(B3;2). A imagem seguinte exibe os resultados obtidos.

c) Soluções adicionais

A título de diversificação e exploração, as seguintes fórmulas também poderiam resultar na conversão desejada:

=MUDAR(B3;5;1;CONCAT(SE(EXT.TEXTO(B3;5;1)={"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"};{0;1;2;3;4;5;6;7;8;9};"")))

=MUDAR(B3;5;1;FILTRO({0;1;2;3;4;5;6;7;8;9};EXT.TEXTO(B3;5;1)={"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"}))

=ESQUERDA(B3;4)&CONCAT(SE(EXT.TEXTO(B3;5;1)={"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"};{0;1;2;3;4;5;6;7;8;9};"")) & DIREITA(B3;2)

=ESQUERDA(B3;4) & FILTRO({0;1;2;3;4;5;6;7;8;9};EXT.TEXTO(B3;5;1)= {"A";"B";"C";"D";"E";"F";"G";"H";"I";"J"}) & DIREITA(B3;2)

Download Planilha Placas Mercosul Excel

Clique no botão abaixo para realizar o  download do arquivo de exemplo: