Como calcular no Excel o 5º(quinto) dia útil do mês

Veja neste artigo como calcular no Excel o 5º (quinto) dia útil do mês no Excel

1. Quinto Dia Útil no Excel - Introdução

No contexto das empresas e colaboradores o 5º dia útil de cada mês é uma data notável, na qual geralmente ocorrem os pagamentos de salários. Setores como Recursos Humanos e Financeiro são especialmente interessados nesta data, que pode ser obtida facilmente no Excel através de cálculos simples com fórmulas.

Nem sempre o 5º dia útil do mês ocorre no dia 05. Desconsiderando sábados e domingos, é até esperado que o 5º dia útil muitas vezes ocorra no dia 07 do mês. Tomando como base o fato de que podemos ainda ter feriados ou datas similares a desconsiderar, como eventos regionais, o Excel perfeitamente dispõe de artifício para contornar estes cálculos, retornando a data correta que representa o 5º dia útil.

Este artigo propõe fórmulas para se obter o 5º dia útil, considerando dois cenários: a) ano e mês informados separadamente (como fev e 2023 em 2 células distintas, por exemplo) e b) data de referência do mês/ano em questão (como 01/02/2023, por exemplo).

2. Soluções com fórmulas

2.1. Com base em ano e mês informados separadamente

A imagem a seguir ilustra o nosso cenário. Note que temos 1 célula (C3, na imagem a seguir) para a escolha do nome do mês (abreviado com 3 letras, mas poderia estar por extenso). Temos também outra célula reservada para inserirmos o ano (C4, na imagem a seguir) referente ao ano desejado. Neste caso, a nossa pretensão será obter o 5º dia útil de novembro de 2022.

Nosso cálculo será baseado na função DIATRABALHO. A imagem a seguir exibe a sintaxe desta função, evidenciando seus argumentos.

Os argumentos desta função são:

data_inicial: data a partir da qual começará a contagem

dias: número de dias úteis que desejamos avançar ou retroceder

[feriados]: lista com datas que deverão ser tratadas como feriados

O 2º argumento, dias, poderá ser negativo. Neste caso, serve para encontrarmos dias úteis anteriores à data inicial. Desta forma, por exemplo, podemos calcular qual foi o 10º dia útil antes de 03/08/2023. Neste caso, para este argumento o valor deverá ficar -10.

O último argumento [feriados], usado para considerar os feriados, requer um intervalo de células com as datas de feriados ou datas genéricas a desconsiderar. De fato, ele requer apenas as datas. Recomenda-se a organização destas datas em formato de tabela para ser atualizada com o passar dos anos. Este argumento é opcional e isto é notório em sua sintaxe em virtude de sua escrita entre colchetes. No entanto, é de extrema importância para cálculos mais precisos. Em nossos cenários, temos uma tabela (visível na próxima imagem) com datas de feriados, chamada tabFeriados.

NOTA: não devemos informar a quantidade de feriados, e sim, informar a lista de feriados.

Para nosso cálculo, os 3 argumentos da função DIATRABALHO ficarão assim definidos:

data_inicial: última data do mês anterior ao mês que serve como base para nosso cálculo

dias: será 5, visto que desejamos o 5º dia útil

[feriados]: campo da tabela com as datas de feriados

O nosso único problema agora está em definir automaticamente o primeiro argumento da função DIATRABALHO, informando a data requerida automaticamente. Faremos isso com a função DATA.VALOR.

Com esta função, concatenaremos a célula contendo o nome do mês abreviado (C3) com a célula contendo o ano (C4). Ao fazer isso, DATA.VALOR retorna a data que será o dia 01 deste mês/ano. Desta forma, por exemplo, se concatenarmos jun e 2023 dentro de DATA.VALOR, o resultado será 01/06/2023.

Após obtermos esta data (que sempre terá o dia 01 de algum mês/ano), subtraímos 1 para obter a data final do mês anterior. Ou seja, para o caso citado, o resultado será 01/06/2023 – 1 dia = 31/05/2023.

A imagem a seguir mostra a fórmula resultante para obtermos o 5º dia útil de novembro de 2022, resultando em 08/11/2022.

Observando o calendário, percebemos que o dia 02/11/2022 (quarta-feira), feriado presente em nossa lista de feriados, faz com que o 5º dia útil deixe de ser o dia 07/11/2022 (segunda-feira), avançando para o dia seguinte, 08/11/2022 (terça-feira).

A fórmula inserida foi =DIATRABALHO(DATA.VALOR(C3&C4)-1;5;tabFeriados[Feriados]). Uma fórmula alternativa que elimina a necessidade de DATA.VALOR poderia ser =DIATRABALHO((C3&C4)-1;5;tabFeriados[Feriados]).

Veja a imagem a seguir com ambas as fórmulas resultando corretamente na mesma data equivalente ao 5º dia útil.

Caso o mês seja representado por seu número, em vez de seu nome, as fórmulas expostas deverão ter uma simples alteração: a concatenação do mês e ano deverá ter também uma barra intermediária. Assim, as fórmulas serão =DIATRABALHO(DATA.VALOR(C3&"/"&C4)-1;5;tabFeriados_[Feriados]) e =DIATRABALHO((C3&"/"&C4)-1;5;tabFeriados_[Feriados]). Cabe comentar que estas 2 fórmulas citadas por último servem para ambos os casos, seja o mês informado através de seu nome (abreviado ou não) ou de seu número.

2.2. Com base em uma data de referência

Podemos ter também o nosso cálculo com base em uma data de referência. Para o exemplo citado, a nossa data de referência será 01/11/2022, mas poderia ser qualquer data de novembro de 2022.

Nossa solução será igualmente baseada na função DIATRABALHO. Como precisamos informar no seu 1º argumento a última data do mês anterior, usamos então a função FIMMÊS. Nós simplesmente não subtraímos 1 de nossa data de referência porque ela pode nem sempre ser o dia 01 do mês em questão. Por isso, FIMMÊS será utilizada. Caso tenhamos certeza de que sempre a data de referência terá o dia 01, poderíamos fazer a simples subtração.

Para a função FIMMÊS, o 1º argumento será a própria data de referência e o 2º argumento será o valor -1, indicando que queremos obter a data do fim do mês anterior em relação à data de referência informada. Em nosso exemplo, a data retornada por FIMMÊS será 31/10/2022, último dia do mês de outubro, mês anterior a novembro.

A imagem a seguir mostra a nossa fórmula que, como esperado, resulta em 08/11/2022.

A fórmula inserida foi =DIATRABALHO(FIMMÊS(C3;-1);5;tabFeriados[Feriados]).

O 1º argumento de DIATRABALHO, que deverá ser a última data do mês anterior, poderá também ser retornado com a função DATA, em vez de FIMMÊS, conforme imagem a seguir, que expõe outra fórmula para o mesmo propósito.

A fórmula alternativa inserida foi =DIATRABALHO(DATA(ANO(C3);MÊS(C3);1)-1;5;tabFeriados[Feriados]). A função DATA inserida poderia ficar com o seu 3º argumento (dia) vazio. Desta forma, ela já retornaria diretamente a última data do mês anterior, sem necessidade de subtrairmos 1. Com este ajuste mencionado, a fórmula seria =DIATRABALHO(DATA(ANO(C3);MÊS(C3););5;tabFeriados[Feriados]).

Download Planilha Exemplo Quinto Dia Útil Excel

Clique no botão abaixo para realizar o  download da planilha de remover duplicidades no Excel, com exemplo de dados: