Como Utilizar a Função FILTRO Excel

Como utilizar a função FILTRO no Excel com artigo com imagens, vídeo-aula e download da planilha de exemplo gratuita.

Sintaxe da Função Filtro Excel

A função Filtro do Excel tem por finalidade retornar uma lista de dados filtrados conforme critérios aplicados.

A sintaxe da função é: =FILTRO(matriz; incluir; [se_vazia])

matriz: matriz aonde estão os dados que desejamos aplicar o filtro.
incluir: determina o filtro a ser aplicado na matriz de origem dos dados.
[se_vazia]: funciona como a função SEERRO, que irá retornar esta informação caso o retorno da função seja vazio.

Exemplo de Aplicação da Função Filtro Excel

Neste exemplo temos uma lista de notas de alunos que desejamos filtrar conforme a matéria, Matemática ou Português.

Para isso usamos esta função: =FILTRO($B$6:$D$31;($D$6:$D$31=I5))

No primeiro parâmetro passamos pra função a origem dos dados, serão os dados filtrados, $B$6:$D$31.

No segundo parâmetro aplicamos ($D$6:$D$31=I5), a sintaxe dele é sempre entre parênteses e nele aplicamos como em funções matriciais a verificação, no caso o intervalo =.

Assim analista de todas as células presentes na matriz de filtro retornam VERDADEIRO, $D$6:$D$31=I5.

Com isso temos o retorno dos dados filtrados conforme abaixo:

Exemplo de Filtro Excel com Mais de Uma Condição

Neste exemplo temos uma filtragem dos dados pela matéria e aluno.

A fórmula aplicada neste exemplo é =FILTRO($B$6:$D$31;($D$6:$D$31=I4)*($B$6:$B$31=I5)).

No primeiro parâmetro temos o intervalo de origem dos dados: $B$6:$D$31

E no segundo parâmetro aplicamos a multiplicação entre duas validações. ($D$6:$D$31=I4)*($B$6:$B$31=I5)

Perceba que agora estamos utilizando não uma, mas duas condições e o * é considerado como E para as condições, fazendo com que as duas sejam aplicadas.

Então o * faz uma multiplicação das condições (VERDADEIRO;VERDADEIRO;VERDADEIRO) * (VERDADEIRO;FALSO;FALSO)) retornaria apenas o primeiro verdadeiro, porque 1*1 é igual a 1(VERDADEIRO) e 1*0 igual a 0(FALSO).

Abaixo temos o retorno dos dados conforme a matéria selecionada e o aluno selecionado.

Exemplo de Filtro com Um Intervalo de Datas

No exemplo abaixo estamos analisando apenas os alunos que tem notas entre 7 e 10.

Para isso usamos a seguinte função: =FILTRO($B$6:$D$31;($C$6:$C$31>=$I$4)*($C$6:$C$31<=I5);"SEM DADOS")

A diferença entre a função anterior e a nova é que usamos >= e <= para verificarmos se a coluna de nota é maior ou menor do que aqueles valores.

E no último parâmetro [se_vazia], passamos um valor padrão se não encontrado, no caso "SEM DADOS".

Abaixo o valor aplicado no filtro conforme vemos na imagem:

Filtrar Dados por Parte do Texto

No exemplo abaixo desejamos filtrar somente os dados conforme parte de um texto.

A fórmula aplicada é =FILTRO($B$6:$D$31;(ÉNÚM(LOCALIZAR(I5;B6:B31)))).

Neste exemplo usamos as funções ÉNÚM para identificar se um número o retorno da função LOCALIZAR é um número, ou seja, se encontrou a parte do texto na célula.

Desta forma temos o retorno de todos os alunos que tem aquela parte do texto conforme vemos abaixo:

Retornar 5 Maiores Textos no Excel

No exemplo abaixo temos um filtro de dados aplicado para retornar os 5 maiores valores.

No exemplo usamos a fórmula =CLASSIFICAR(FILTRO($B$6:$D$31;($C$6:$C$31>=MAIOR($C$6:$C$31;I5)));2;-1).

A função MAIOR retorna o x maior valor na nossa planilha e no intervalo ($C$6:$C$31>=MAIOR($C$6:$C$31;I5) estamos aplicando uma verificação se os valores da coluna Nota são maiores ou iguais ao 5.º maior valor no caso.

Após isso aplicamos a função CLASSIFICAR para classificar os dados do retorno do filtro.